NTC Thermistor with Ring Lug

Description

This NTC thermistor is thermally attached to a tin plated copper ring lug which makes it ideal for monitoring the surface temperature of what it is attached to, such as a heatsink.

PACKAGE INCLUDES:

• NTC Thermistor with Ring Lug

KEY FEATURES OF NTC THERMISTOR WITH RING LUG:

This NTC thermistor is thermally attached to a tin plated copper ring lug with an M3-4 hole for mounting.  38mm long 24AWG pig-tail wires are attached and strain-relieved with epoxy.

Thermistors are essentially resistors whose resistance value changes with changes in temperature.  NTC stands for ‘Negative Temperature Coefficient which means that the sensor resistance will decrease as temperature increases.

The sensor is capable of reading temperature in the range of -40 to +150°C with an accuracy of 5%.

Our Evaluation Results:

This is a commonly used sensor for basic temperature measurement.  This one has rugged construction which is nice for more demanding applications. Once up and running with a microcontroller, it is easy to test the sensor by using the fingers to warm it and monitor the output.

This thermistor has a nominal value of 10K at 25C.  If the thermistor is placed in series with a 10K resistor across Vcc and ground, that creates a voltage divider.  As the thermistor warms up, its resistance lowers and the analog output increases towards Vcc (assuming the thermistor is on the Vcc side of the voltage divider).

Using the device requires some math to convert from the voltage output to the temperature.  In our own test code, we use the Beta method for temperature calculation, but there are several different formulas that can be used.  The nice thing about the Beta method is that you can measure your component values and enter them into the fields if your sensor is constructed a little different.

The Beta value comes from the spec sheet.  Balance_Resistor is the measured value of the resistor placed in series with the Thermistor.  Resistor_Room_Temp is the measured value of the thermistor at the current room temperature.  Room_Temp is the current room temp (in Kelvin) where the testing is taking place.  Kevin can be calculated by taking the temperature in degrees C and adding 273.15.

NTC Thermistor Test Program

/*
NTC Thermistor module test

Basic code for reading the output of the thermistor. It uses the Beta method of calculating
the temperature.  Beta # are from spec sheet
*/
#define THERMISTOR_PIN A0                   // Use any available ADC pin

const double BALANCE_RESISTOR   = 10000.0;  // Measured value of on-board divider resistor
const double MAX_ADC            = 1023.0;  // Max number of ADC steps (10-bit in this case)
const double BETA               = 3984.0;   // Beta value (from datasheet)
const double ROOM_TEMP          = 293.95;   // room ambient temperature in Kelvin
const double RESISTOR_ROOM_TEMP = 12267.0;  // Measured value of thermistor at room temp

double currentTemperature = 0;  // Variable to hold measured temperature
//===============================================================================
//  Initialization
//===============================================================================
void setup() 
{ 
  Serial.begin(9600);  // Set comm speed for debug window messages
}
//===============================================================================
//  Main
//===============================================================================
void loop() 
{
  currentTemperature = readThermistor();
 
  Serial.print("Current Temp is ");
  Serial.print(currentTemperature);
  Serial.print("C  /  ");
  Serial.print(currentTemperature * 9 / 5 +32);
  Serial.println("F");

   delay(3000);
}
//===============================================================================
//  Functions
//===============================================================================
double readThermistor() 
{
  // Local Variables
  double rThermistor = 0;            // Thermistor resistance value
  double tKelvin     = 0;            // Calculated temperature in Kelvin
  double tCelsius    = 0;            // Calculated temperature in celsius
  int    adcSample   = 0;            // ADC measurement

  adcSample = analogRead(THERMISTOR_PIN);  // read from pin and store
 
  rThermistor = BALANCE_RESISTOR * ( (MAX_ADC / adcSample) - 1);

  tKelvin = (BETA * ROOM_TEMP) / 
            (BETA + (ROOM_TEMP * log(rThermistor / RESISTOR_ROOM_TEMP)));

  tCelsius = tKelvin - 273.15;  // convert kelvin to celsius 

  return tCelsius;    // Return the temperature in Celsius
}

Notes: 

1. None

Technical Specifications